StockFetcher Forums · Filter Exchange · Alpha Filter based on Ron Groenke Visions V<< 1 2 3 4 5 ... 9 >>Post Follow-up
SAFeTRADE
630 posts
msg #146465
Ignore SAFeTRADE
2/7/2019 12:39:24 PM

Fetcher[set{bla, high 10 day high - low 10 day low}
set{blb, bla * .25}
set{bl, low 10 day low + blb}

set{bra, bl - close}
set{brb, bra / blb}
set{br, 10 * brb}

set{taa, ma(10) * 2}
set{tab, taa - close}
set{tac, ma(10) / tab }
set{tad, tac + 1}
set{tai, br * tad}

set{pointb1, bla * .125}
set{pointb, bl + pointb1}

set{pointc, low 10 day low + pointb1}

draw ma(20)
draw ema(9)
draw ma(50)
draw bl on plot price


add column separator
add column tai
add column bl
add column separator
set{gr, count(tai above 10,1)}
set{ta, count(tai between -5 and 10,1)}
set{wait, count(tai between -10 and -4.9,1)}
set{bad_idea, count(tai below -10,1)}
set{alpha_start, count(tai below -50,1)}
set{alpha_end, count(tai crossed above -30,1)}

add column gr{get_ready}
add column ta{take_action}
add column wait
add column bad_idea
add column separator
add column alpha_start
add column alpha_end
add column separator

draw tai line at -50
draw tai line at -10
draw tai line at -5
draw tai line at -31

draw alpha_start
draw alpha_end
draw Slow Stochastics Fast %K(5,5)
draw Slow Stochastics Fast %K(12,3,3)

chart-length is 6 months

symlist(spy,dia,qqq,sds,spxl,vxxb)
]



Here is a little code I have been playing with for a while. Buy when you have alpha_start signal
and sell when you have alpha_end signal. Seems to work best when Stochastics are over bought
or nearly over bought. No, this has not been back tested. Tweak as you like. Also seems works best
when at a key MA level.

davesaint86
725 posts
msg #146466
Ignore davesaint86
2/7/2019 12:57:00 PM

If there is a 1 in Bad Idea and a 1 in Alpha Start I assume you do not buy still until the Bad Idea turns to 0.

SAFeTRADE
630 posts
msg #146468
Ignore SAFeTRADE
modified
2/7/2019 2:13:53 PM

No, bad_idea means the train has left the station. Buy on dips. Alpha_start will flash only when
bad_idea is activated. Study TAI and see when and where it moves. When bad_idea turns
to 0 run is over.

nibor100
1,010 posts
msg #146485
Ignore nibor100
2/9/2019 3:58:29 PM

@SAFeTRADE,

Did the idea for your interesting filter come from any of his books?

Thanks,
Ed S.

SAFeTRADE
630 posts
msg #146491
Ignore SAFeTRADE
2/9/2019 8:51:14 PM

Yes, his book "Cash for Life" and the rules which are on his website.

Safetrade

dtatu
143 posts
msg #146493
Ignore dtatu
2/9/2019 11:06:14 PM

It looks good, at the first glance, this filter.
If anybody can backtest it?

Cheese
1,374 posts
msg #146499
Ignore Cheese
2/10/2019 12:09:19 AM

Thank you, SAFeTRADE
Is this summary chart still pertinent?


Cheese
1,374 posts
msg #146500
Ignore Cheese
2/10/2019 12:15:15 AM

SAFeTRADE, you had another Groenke thread in 2015
and jdinkel's version seemed pretty close to specs by Ron Groenke.
But jdinkel's version seemed to be unfinished and abandoned.
What seems to be missing and what would it take to finish it?
Thank you, SAFeTRADE.

Fetcher[

/* jdinkel modified 12/17/2017 */
/* https://www.stockfetcher.com/forums/Filter-Exchange/The-Ron-Groenke-V-Theory/124548/-1/140165 */

/* Another member: http://www.stockfetcher.com/forums///54752/-1/54752 */
/* SAFeTRADE: http://www.stockfetcher.com/forums2/Filter-Exchange/The-Ron-Groenke-V-Theory/124548/-1/124548 */
/**** Calculate the Lower 25 as lower25 = 0.25 x (52 week high - 52 week low) */
set{hi52w, High is 52 week High} /* Step 1 - get 52 week high for underlying */
set{lo52wVpointA, Low is 52 week Low} /* Step 2 - get 52 week low for underlying */
set{range52w, hi52w-lo52wVpointA} /* Step 3 - Calculate the range from low to high */
set{lower25, range52w * 0.25} /* Step 4 - Calculate the bottom quarter of the range */
/**** Calculate the Buy Limit as BL = Buy Limit = 52 week low + lower25 */
set{buylimit, lower25 + lo52wVpointA} /* Step 5 - BL - Buy Limit - The max price you should pay for the stock. */
/**** Calculate the Buy Rank as 10 x ( (buylimit - close) / lower25 ) where close is the current price */
set{blcl, buylimit - close}
set{brTop, blcl * 10}
set{buyrank, brTop / lower25}
/**** Calcualte the Take Action Indicator as tai = buyrank x (1 + FDA/(2 x FDA - close)) */

set{fda, MA(50)} /* FDA = 50 day moving average */
set{2fda, 2*fda}
set{2fdacp, 2fda - close}
set{fdadiv, fda / 2fdacp}
set{fdaplus, 1 + fdadiv}
set{tai, buyrank * fdaplus} /* Get Ready >=10, Take action >=-5 & <10, Wait >=-10 & < -5, Bad Idea <-10 */

find optionable stocks
/* From Show me the Trade Ch2 - Trading in the V 20 days or more */
and the count(tai > -5,25) is above 20
and the count(tai <= 10,25) is above 20
/* From Show me the Trade Ch2 - Stock is going up last 3 days */
close has been increasing for 3 days

/* Probably best to keep the trading to stocks that can have a few strikes below ATM */
and the price is more than 10

and add column hi52w
and add column lo52wVpointA
and add column buylimit
and add column buyrank
and add column tai
/* Great idea from SAFeTRADE to add a graph of the tai with the indicators as sortable columns */
set{gr, count(tai above 10,1)}
set{ta, count(tai between -5 and 10,1)}
set{wait, count(tai between -10 and -5,1)}
set{bad_idea, count(tai below -10,1)}
add column gr{get_ready}
add column ta{take_action}
add column wait
add column bad_idea
add column separator
sort column 12 descending /* take action indicator > 1 to the top*/

/* Plot the take action indicator and show the trading indicator lines. We are looking for anything between -5 and 10 */
draw tai line at 10
draw tai line at -5
draw tai line at -10

/* Calculate the Gold $ Calculation */
/* 10 x number of up days + 2 x number of days in Vision View V + 30 or 0 */
/* 30 if the stock is in the Visions View V or price in the 50 day average range, 0 if it is not. */
/* The ideal case is when the stock is trading in the Visions View V for 20 days, going up the last three days, and within 5% of the 50 day moving average. */
set{fda5pctabove, fda * 1.05}
set{fda5pctbelow, fda * 0.95}
draw fda
draw fda line at fda5pctabove
draw fda line at fda5pctbelow
set{cntUnder, count(fda < fda5pctabove,20)}
set{cntAbove, count(fda > fda5pctbelow,20)}
set{aggregate, cntUnder + cntAbove}
/*set{trigger, count(aggregate>1,20)}
draw trigger*/
/* what am I doing wrong? out of variables? */



draw ta /* Creates a nice set of dots, one for each day where the trade meets the criteria - I find it easier to see than the lines */
]



Cheese
1,374 posts
msg #146501
Ignore Cheese
2/10/2019 12:37:59 AM

SAFeTRADE,
I also have some honest observations, as a complete Groenke noob.
jdinkel's tai and other charts seemed to maintain some sort of trends.
Yours seemed to look like bounded oscillators,
Are trends not important with this strategy?
Are you sacrificing trends in order to highlight buy and sell points?
Thank you, SAFe.

SAFeTRADE
630 posts
msg #146505
Ignore SAFeTRADE
2/10/2019 9:32:30 AM

The only difference in mine and Groenke's is I changed 50 day numbers to 10 day. Ron Groenke used TAI "take action indicator" as well..an indicator. Shows you at a glance what to do. Do not try to trade the TAI
blindly. Example; TAI signals to "take action" did it enter the zone from above -5 or from below-10. It
makes a difference. Look at how TAI works on the chart.

Have not looked at jdinkel's version. May look at it later. Thanks for your interest in Groenke filter.

StockFetcher Forums · Filter Exchange · Alpha Filter based on Ron Groenke Visions V<< 1 2 3 4 5 ... 9 >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2022 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.