StockFetcher Forums · Filter Exchange · Swing Trading with Larry Connors<< 1 2 >>Post Follow-up
xarlor
561 posts
msg #150631
Ignore xarlor
modified
2/2/2020 1:36:24 AM

Swing Trading with Larry Connors

Over the past few months, there have been requests for swing trading filters. As has been pointed out by several members on SF over the years, Larry Connors' quantitative strategies continue to be some of the best swing trades in existence. That is because human emotion never changes. Fear and greed rule the market. I recommend his books wholeheartedly.

Personally, I'rve had success with his strategies. These are not home-run trades, they are base hits at best. However, they are frequent and keep you engaged if you're itching for action. Average gains are around 1% for 3-7 day trades. Compounded over a year, these base hits add up quickly.

I am posting all the Larry Connors filters I've coded and personalized for my use during my history with SF. Some are modified from other members' existing filters.

It is my hope this will satisfy future requests of swing trade filters.

Enjoy!

Larry Connors Cumulative RSI(2)



Fetcher[
/* Buy when 2-day sum of RSI(2) < 50. Sell when crosses above 65 */

symlist(EEM,EWW,EWZ,FXI,GLD,HYG,QQQQ,SLV,SPY,TLT,USO,SBI,XLE,XLF,XLP,XLU,XOP,XRT)
close > ma(200)
average volume(100) > 250000
set{RSIC,rsi(2) + rsi(2) 1 day ago}
set{buy,count(RSIC crossed below 50,1)}
buy > 0
set{sell,count(RSIC crossed above 65,1)}
sell > -1
draw RSIC line at 50
]




Larry Connors Double 7s



Fetcher[
/* Buy when close at a 7-day low. Sell when close at 7-day high */

symlist(EEM,EWW,EWZ,FXI,GLD,HYG,QQQQ,SLV,SPY,TLT,USO,SBI,XLE,XLF,XLP,XLU,XOP,XRT)
close > ma(200)
average volume(100) > 250000
set{7lo1,count(close < close 1 day ago,1)}
set{7lo2,count(close < close 2 days ago,1)}
set{7lo3,count(close < close 3 days ago,1)}
set{7lo4,count(close < close 4 days ago,1)}
set{7lo5,count(close < close 5 days ago,1)}
set{7lo6,count(close < close 6 days ago,1)}
set{buy1,7lo1 * 7lo2}
set{buy2,buy1 * 7lo3}
set{buy3,buy2 * 7lo4}
set{buy4,buy3 * 7lo5}
set{buy,buy4 * 7lo6}
buy > 0

set{7hi1,count(close > close 1 day ago,1)}
set{7hi2,count(close > close 2 days ago,1)}
set{7hi3,count(close > close 3 days ago,1)}
set{7hi4,count(close > close 4 days ago,1)}
set{7hi5,count(close > close 5 days ago,1)}
set{7hi6,count(close > close 6 days ago,1)}

set{sell1,7hi1 * 7hi2}
set{sell2,sell1 * 7hi3}
set{sell3,sell2 * 7hi4}
set{sell4,sell3 * 7hi5}
set{sell,sell4 * 7hi6}
sell > -1
]




Larry Connors RSI(2)



Fetcher[
/* Buy at the close. Close position when close crosses above MA(5) */

optionable
aaverage volume(30) > 1234567
low > ma(200)
set{buy1,count(rsi(2) crossed below 5,1)}
set{buy2,count(close > ma(200) for last 100 days,1)}
set{buy,buy1 * buy2}
buy > 0
set{sell,count(closed crossed above ma(5),1)}
draw sell
draw rsi(2) line at 5
draw rsi(2) line at 95
draw ma(5)
]



Larry Connors: Buying into Further Weakness Intra-day



Fetcher[
/* Intraday buy at 10d. Sell at close 5 days later */

close > 5
close > ma(200)
average volume(100) > 250000

close 1 day ago < low 10-day low 2 days ago
set{10d,close 1 day ago * .90}
low <= 10d

add column 10d
draw price line at low 10-day low 2 days ago
draw price line at 10d

do not draw low 10-day low
do not draw 10d
]



Larry Connors RSI Powerzones Long



Fetcher[
/* Buy the close. Sell when RSI(4) crosses above 55. Buy another unit if close is below RSI(4) 20 while still in the position.

Modified from KSK8s filter https://www.stockfetcher.com/forums/Filter-Exchange/Larry-Connors-RSI-Powerzones-Long-Strategy/146456
*/

market not etf
set{x1, count(close > ma(200) for last 100 days,1)}
set{x2, count(rsi(4) crossed below 25,1)}
set{buy, x1*x2}
set{sell, count(rsi(4) crossed above 55,1)}

buy > 0

draw buy
draw sell
draw rsi(4) line at 25
draw rsi(4) line at 55

average volume(30) > 2000000
close between 30 and 70
close > wma(150)
]



Larry Connors 52-week high, retraction, bounce



Fetcher[
/* Buy at 7below or lower. Exit when Connors RSI crosses above 70 */

market not etf
close > 5
average volume(21) > 1000000

set{7below,close 1 day ago * .93}
set{10below,close 1 day ago* .90}

set{var1,count(high reached a new 52-week high,20)}
set{var2,count(Connors RSI(3,2,100) 1 day ago < 15,1)}
set{var3,count(low < 7below,1)}
set{Buy1,var1 * var2}
set{Buy,buy1 *var3}
buy > 0

set{Exit,count(Connors RSI(3,2,100) crossed above 70,1)}

draw Exit
draw price line at 7below
draw price line at 10below
add column 7below
add column 10below

draw Connors RSI(3,2,100) line at 15
draw high 52-week high
]



Larry Connors TSP



Fetcher[
/* Buy at the close. Sell when RSI(2) > 70 */

market is etf
average volume(20) > 250000

low > ma(200)
set{var1,count(RSI(2) 3 days ago < 25,2)}
set{var2,count(close < close 1 day ago,3)}
set{Buy,var1 + var2}

set{Sell,count(RSI(2) > 70,1)}

buy equals 5
sell > -1

draw RSI(2) line at 25
draw RSI(2) line at 70
]



Larry Connors Terror Gap



Fetcher[
/* Intraday trade. If ticker appears, set a Limit Buy order at the Limitbuy price listed. Sell when Connors RSI(3,2,100) > 70 */

market etf
average volume(20) > 250000

set{var1,count(Connors RSI(3,2,100) 1 day ago < 5,1)}
set{var2,count(close-to-open gap < -1,1)}
set{Watch,var1 * var2}
watch > 0

set{Limitbuy,open * .975}
add column Limitbuy
draw price line at Limitbuy

set{sell,count(Connors RSI(3,2,100) > 70,1)}
sell > -1


draw Connors RSI(3,2,100) line at 5
draw Connors RSI(3,2,100) line at 70
]



Larry Connors CRASH



Fetcher[
/* Short the next day with limit of ShortPrice or buy deep ITM Puts at -80 Delta. Exit when ConnorsRSI crosses under 30 */

market not etf
optionable

set{var1,count(close > 5,1)}
set{var2,count(average volume(21) > 1000000,1)}
set{var3,count(historical volatility(100,1) > 100,1)}
set{var4,count(Connors RSI(3,2,100) > 90,1)}
set{short1,var1 * var2}
set{short2,short1 * var3}
set{short,short2 * var4}
short > 0

set{Cover,count(Connors RSI(3,2,100) < 30,1)}
cover > -1

set{ShortPrice,close*1.05}
add column shortprice
add column sector

draw Connors RSI(3,2,100) line at 90
draw Connors RSI(3,2,100) line at 30
]



Larry Connors VXX Short



Fetcher[
/* Short at close only 20% of full position. If close is higher than entry price, short another 30% of full position. If close is higher than 2nd entry price, short 50% of a full position. Cover when close < ma(5) */

symlist(VXX)

set{var1,count(close > ma(5),1)}
set{var2,count(rsi(4) > 70,1)}

set{Short,var1 * var2}
short > 0
draw short

set{Cover,count(close < ma(5),1)}
draw cover
]



Samhill
5 posts
msg #150658
Ignore Samhill
2/4/2020 10:49:30 AM

Thanks! Any favorites? Have you noticed higher percentages with any particular filter?

stephenmcmahon83
15 posts
msg #150659
Ignore stephenmcmahon83
modified
2/4/2020 11:38:41 AM

Here is another filter for shorting stocks that Larry Connors shared several years ago. Short today if price is >= 8% higher than yesterdays close. Exit when the CRSI indicator closes below 30

Fetcher[
show stocks where close is greater than 5 and
average volume(20) is greater than
500,000 and where Connors RSI(3,2,100) is greater than 85
and Historical Volatility(100,1) is greater than 40
and adx(10) is greater than 40
and where high divided by close from 1 day ago is greater than 1.079
set{trigger, close * 1.08}
and add column Connors RSI(3,2,100)
and add column MA(5)
and add column PE Ratio
and add column high
and add column low
add column optionable
add column trigger
draw MA(5)
draw Connors RSI(3,2,100)
sort column 3 descending
and High 1 day ago Reached a New 10 Day High
]



miketranz
956 posts
msg #150662
Ignore miketranz
2/4/2020 8:28:54 PM

Fetcher[close above MA(200)
average volume(50) above 100000
close below close 1 day ago
RSI(2) 1 day ago below 2

draw RSI(2) line at 70
draw MA(5)
draw price line at MA(5)

add column RSI(2) {RSI(2)}
add column MA(5) {MA(5)}
sort on column 5 ascending
]

NOTE:Larry Connors filter from a decade ago,posted by Chetron.Mind boggling stats:80.36% of trades net gain/111% ROI vs SPY -8.82.I wonder how this filter would hold up under the current trading environment.Remember,this was a long side filter in bear market.Thanks for sharing this post.Best,Miketranz...

sandjco
648 posts
msg #150665
Ignore sandjco
2/4/2020 10:19:03 PM

Thank you for sharing!

Cheese
1,374 posts
msg #150666
Ignore Cheese
2/4/2020 11:21:24 PM

miketranz 2/4/2020 8:28:54 PM
close above MA(200)
average volume(50) above 100000
close below close 1 day ago
RSI(2) 1 day ago below 2

draw RSI(2) line at 70
draw MA(5)
draw price line at MA(5)

add column RSI(2) {RSI(2)}
add column MA(5) {MA(5)}
sort on column 5 ascending]

NOTE:Larry Connors filter from a decade ago,posted by Chetron.
Mind boggling stats:80.36% of trades net gain
====================================================

Thank you for that great filter, mike.

Perhaps because of my own limitations, Im still trying to figure out how to use the other filters in this thread but I do thank you for sharing.

KSK8
561 posts
msg #150672
Ignore KSK8
2/5/2020 10:00:17 AM

Big fan of Larry Connors. Keep pumping out filters guys!

Cheese
1,374 posts
msg #150673
Ignore Cheese
2/5/2020 10:33:36 AM

miketranz 2/4/2020 8:28:54 PM
close above MA(200)
average volume(50) above 100000
close below close 1 day ago
RSI(2) 1 day ago below 2

draw RSI(2) line at 70
draw MA(5)
draw price line at MA(5)

add column RSI(2) {RSI(2)}
add column MA(5) {MA(5)}
sort on column 5 ascending]

NOTE:Larry Connors filter from a decade ago,posted by Chetron.
Mind boggling stats:80.36% of trades net gain
====================================================

That filter was originally written and backtested by Kevin_in_GA
Chetron then did more backtesting
More interesting details can be found here:

https://www.stockfetcher.com/forums/General-Discussion/EVALUATING-LARRY-CONNORS-ETF-TRADING-STRAEGY/86481/-1/86481

Thanks again, miketranz


graftonian
1,089 posts
msg #150677
Ignore graftonian
2/5/2020 2:25:00 PM

check out Kevin-in-GA post msg #93841

Cheese
1,374 posts
msg #150678
Ignore Cheese
2/5/2020 4:04:06 PM

Kevin_in_GA post msg #93841 is here
https://www.stockfetcher.com/forums/Filter-Exchange/HIGH-PROBABILITY-ETF-TRADING-BY-LARRY-CONNORS-GET-YOUR/93830


StockFetcher Forums · Filter Exchange · Swing Trading with Larry Connors<< 1 2 >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2022 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.