StockFetcher Forums · View by Author: xarlor (116 messages) ·  [ Display By: Date / Subject ]<< 1 ... 2 3 4 5 6 ... 12 >> 
Filter Exchange · Here is code to place a version of Heikin Ashi on your chart.
xarlor
msg #149505
10/31/2019 5:51:40 PM

This definitely will require Advanced sub, but I made a histogram out of green/red Heikin Ashi candles. A count of 2 is green candle and a count of 1 is red candle. It makes it easier at a glance to see if the trend is bullish, negative, or choppy.

Fetcher[
set{cls1,open + high}
set{cls2,cls1 + low}
set{cls3,cls2 + close}
set{cls,cls3 / 4}

set{op1, open 1 day ago + close 1 day ago}
set{op, op1 / 2}

set{hi1,max(high,op)}
set{hi,max(hi1,cls)}

set{lo1,min(low,op)}
set{lo,min(lo1,cls)}



draw hi
draw lo on plot hi

set{trend,count(cls > op,1) + 1}
draw trend

do not draw cls
do not draw op

set{lri60, lri(60)}
set{lri20, lri(20)}

close > 5
close < 100
average volume(30) > 750000
optionable

draw lri(20)
draw lri(60)

add column RSquared(close, 60)
sort column 5 descending
]



Filter Exchange · Here is code to place a version of Heikin Ashi on your chart.
xarlor
msg #149502
10/31/2019 1:48:45 PM

I see what you're doing.

In your code, me thinks you have hi incorrect. Right now you're asking SF for the max between high, close, and open, which is always going to =high regardless. Likewise with lo, you're asking for the min of open, low, and close which will always =low.

You forgot the cls component too (open+high+low+close)/4. I think you meant:

Fetcher[
set{cls1,open + high}
set{cls2,cls1 + low}
set{cls3,cls2 + close}
set{cls,cls3 / 4}

set{op1, open 1 day ago + close 1 day ago}
set{op, op1 / 2}

set{hi1,max(high,op)}
set{hi,max(hi1,cls)}

set{lo1,min(low,op)}
set{lo,min(lo1,cls)}

add column cls
add column op
add column hi
add column lo
]



Filter Exchange · How to code reversal in indicator values
xarlor
msg #149501
10/31/2019 1:23:44 PM

Down to up

Fetcher[
ma(50) > ma(50) 1 day ago
ma(50) 1 day ago decreasing for last 5 days
]



Up to down

Fetcher[
ma(50) < ma(50) 1 day ago
ma(50) 1 day ago increasing for last 5 days
]



Public Filter List · Float
xarlor
msg #149490
10/30/2019 8:48:22 PM

Float, no. But shares outstanding is a close approximation.

Fetcher[
symlist(amd,aapl,fb,amzn)
add column shares outstanding
]



Stock Picks and Trading · Weinstein Filters
xarlor
msg #149439
10/27/2019 3:23:28 PM

I don't know. The way I interpreted it:

Using Weinstein on the weekly is for investors, i.e. long term holds 6+ months.
Using Weinstein on the daily is for traders - less than 6 months.

If you do Weinstein daily and Guppy daily, you can see the entry for both is the exact same day for RGLY.



General Discussion · count occurences , help needed
xarlor
msg #149437
10/27/2019 3:10:01 PM

Yes, SF has a limit of 1 year's worth of trading days (252 days) on any single indicator. You have to do some trickery to include multiple years.

Here is your filter that gives the number of times there have been 9 green candles in a row within the last 4 years (1008 trading days). A result of 1 means this is the first time it has happened in 4 years. The results are sorted from lowest number of occurrences to highest.


Fetcher[
chart-time is 3 year
set{var9,count(close > open,9)}

set{y1,count(var9 > 8,252)}
set{y2,count(var9 1 year ago > 8,252)}
set{y3,count(var9 2 years ago > 8,252)}
set{y4,count(var9 3 years ago > 8,252)}

set{z1,y1 + y2}
set{z2,z1 + y3}
set{z3,z2 + y4}

var9 > 8

add column y1
add column y2
add column y3
add column y4

add column z3 {No times in last 4 years}

draw var9 line at 9

sort by column 9 ascending
close 3 years ago > 0
]



General Discussion · Drummond Geometry
xarlor
msg #149436
10/27/2019 2:42:01 PM

Fetcher[
// Daily PLdot based on daily HLC prices of last 3 days
// Weekly PLDot based on weekly HLC prices for last 3 weeks

// Show stocks which are above Daily and weekly Pldots
// Show stocks which are below Daily and Weekly Pldots

close > 10

// Daily PLDot

set{x1,high + low}
set{x2,x1 + close}
set{x3,x2 / 3}

set{y1,x1 1 day ago}
set{y2,x2 1 day ago}
set{y3,y2 / 3}

set{z1,x1 2 days ago}
set{z2,x2 2 days ago}
set{z3,z2 / 3}

set{var1,x3 + y3}
set{var2,var1 + z3}
set{DPLdot,var2 / 3}

// Weekly PLDot

set{j1,weekly high + weekly low}
set{j2,j1 + weekly close}
set{j3,j2 / 3}

set{k1,j1 1 week ago}
set{k2,j2 1 week ago}
set{k3,k2 / 3}

set{l1,j1 2 weeks ago}
set{l2,j2 2 weeks ago}
set{l3,l2 / 3}

set{var10,j3 + k3}
set{var11,var10 + l3}
set{WPLdot,var11 / 3}

// Above (Buy) or Below (Sell)

set{buy1,count(close > DPLdot,1)}
set{buy2,count(close > WPLdot,1)}
set{BUY,buy1 * buy2}

set{sell1,count(close < DPLdot,1)}
set{sell2,count(close < WPLdot,1)}
set{SELL,sell1 * sell2}

set{trigger,buy + sell}
trigger > 0
do not draw trigger

// Numbers, lines, and stuff

add column buy
add column sell
add column DPLdot
add column WPLdot
draw price line at DPLdot
draw price line at WPLdot

// There are three types of people in this world. Those who can count and those who can't.
]



General Discussion · count occurences , help needed
xarlor
msg #149430
10/26/2019 2:42:49 PM

As an example this will show you stocks that had 9 straight green candles in a row. It ill also show you a histogram of the number of green candles in a row.

Fetcher[
set{var1,count(close > open,9)}
var1 > 8
]



If you prefer an oscillator instead of a histogram:

Fetcher[
chart-time is 1 year
set{var1,count(close > open,9)}
var1 > 8
draw var1 line at 9
]



General Discussion · Filter out prior day results
xarlor
msg #149416
modified
10/25/2019 10:43:35 AM

My solution would be to use count for past 2 days and only return the results where the condition happened once. This will exclude any results that happen 2 days in a row.

Example without count.
AAPL condition triggered yesterday and today
MSFT condition only triggered today

Fetcher[
symlist(MSFT,AAPL)
ma(3) > ma(7)
]



Example with count:
Only show results that triggered today but not yesterday.

Fetcher[
symlist(MSFT,AAPL)
ma(3) > ma(7)
set{var1,count(ma(3) > ma(7),2)}
var1 between 0 and 2
]



Stock Picks and Trading · Weinstein Filters
xarlor
msg #149405
10/24/2019 5:07:45 PM

Weinstein's works well when the market is doing well. Remember, one of the main principles of his methodology is comparing the individual stock to its sector AND to the market as a whole. Since the market has been... shall we say "choppy" since August, there haven't been many good candidates. At least on the long side. He has rules for shorting during bear markets as well, but again it's been a sideways market more than a bull or bear market.

I still look for candidates and have entered a few. Bought a long call on ABR during a strong signal back in August. Broke wma(150) on strong volume after clearing a head and shoulders pattern. It was a beautiful set-up. Of course, it immediately turned around (twice). Held onto it though and am up 86% for now. The method worked, but it decided to take me for a ride before the climb.

I posted it before, but here is the Stage 2 filter I made for myself:

Fetcher[
chart-time is 3 years
optionable
market not etf


set{var1,average volume(5) 1 day ago}
set{var2,var1*2}
volume > var2
volume > 500000
close > 5
close crossed above wma(150)
close 1 day ago < wma(150) for last 30 days

add column sector
Relative Strength(^SPX,150) > 1.0
30-day slope of Relative Strength(^SPX,150) > 0

add column var1
add column var2

draw high 3-year high
draw high 2-year high
draw high 1-year high
add column high 1-year high
add column high 2-year high
add column high 3-year high
]





StockFetcher Forums ·  · << 1 ... 2 3 4 5 6 ... 12 >>

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2018 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus