StockFetcher Forums · Filter Exchange · Making an ETF ladder<< >>Post Follow-up
JoeyVinyl
124 posts
msg #151684
Ignore JoeyVinyl
modified
4/3/2020 3:20:53 PM

For anyone not familiar with the concept of a CD ladder (Certificate of Deposit), let's say you take $10,000 and divide it into five piles of $2,000 each. You use those piles to buy five CD's with different lengths. A 1 year, a 2 year, a 3 year, etc. so you end up with a CD that comes to term every year for the next five years. When the first four come to term you use that money to buy another 5 year CD. Now you have five 5 year CD's with one coming to term every year. Personally I never had enough money to do this and get a decent rate of return. For some people, however, this is a nice safe investment.

But we're not here for safe investments, are we? No, we don't want to take crazy risks either. That's why we're using filters and indicators and some degree of technical analysis. None of them are perfect; none of them work all the time. These days, with the market going up, down, and sideways - usually within the same hour - none of my filters are helping me much, if at all. One of the obvious ways to reduce risk right now is to stay out of the market, but it's just as obvious that means no profit either. Another way is to buy ETFs instead of individual stocks. I decided to stick with the commission free ETFs offered by my broker and make an ETF ladder, similar to a CD ladder, but with a much shorter time frame.

This filter takes two ideas I've seen here and combines them using multiple time frames. One is the relative strength of the ETF compared to the S&P 500 index; the other is the rate of return. I plan on buying one ETF every week for four weeks, then selling the oldest and buying a new one. I'll be holding them for 28 days so calendar months won't be important here. I have this sorted by the relative strength column so I can find the one that has the best average RS of the last 28 days. Then I look at the average rate of return (ror in this filter) and decide which one I like best. I'll buy it at open on whatever day I start this then sell it at open 28 days later, buying the one I like best from the filter closer to that day. My hope is that by filtering out ones that have an overall negative rate of return that I can at least get some gains from these. We'll see what happens.

As usual with any filters I post here, you are all welcome to use it as is or make changes that make it your own.

Fetcher[market is ETF

set {rs1, relative strength(^INX,7)}
set {rs2, relative strength(^INX,14)}
set {rs3, relative strength(^INX,21)}
set {rs4, relative strength(^INX,28)}
set {rsum1, rs1 + rs2}
set {rsum2, rs3 + rs4}
set {rsum3, rsum1 + rsum2}
set {rsavg, rsum3 / 4}

set {ror07a, close - close 7 days ago}
set {ror07b, ror07a / close}
set {07day, ror07b * 100}

set {ror14a, close - close 14 days ago}
set {ror14b, ror14a / close}
set {14day, ror14b * 100}

set {ror21a, close - close 21 days ago}
set {ror21b, ror21a / close}
set {21day, ror21b * 100}

set {ror28a, close - close 28 days ago}
set {ror28b, ror28a / close}
set {28day, ror28b * 100}

set {avg1, ror07b + ror14b}
set {avg2, ror21b + ror28b}
set {avg3, avg1 + avg2}
set {avg4, avg3 / 4}
set {avgror, avg4 * 100}

close is < 55
rsavg is > 1
avgror is > 0

do not draw rsavg
do not draw avgror
draw ema(14)
draw ema(28)

add column rsavg {rel strength}
add column separator
add column 07day {7d ror}
add column 14day {14d ror}
add column 21day {21d ror}
add column 28day {28d ror}
add column avgror {avg. ror}

sort column 11 descending
]



EDIT: I'm posting an edited version of this filter because I noticed some math errors and corrected them.


Cheese
1,049 posts
msg #151695
Ignore Cheese
4/4/2020 1:19:05 PM

@JoeyVinyl,

Thank you for sharing your novel idea of ETF laddering using relative strengths.

I remember last June 2019, Paula pa247 mentioned Dorsey and Mansfield as two other uses of relative strengths.

The 2019 Weinstein posts showed that signals from those relative strengths worked most of the time,
and they were perplexing some of the time.

Then pa247 started posting many good trades after she got her Chartmill subscription (at half price.)
So, it would appear that some of Chartmill secret sauces like their Stage Analysis might have added value
to pa247 trades and uses of relative strengths.

https://www.stockfetcher.com/sfforums/?q=byuser&author=pa247
https://www.stockfetcher.com/sfforums/?mid=148901
https://www.stockfetcher.com/forums/General-Discussion/Mansfield-RS-question/148217/0

Maybe there is something there in sF or Chartmill for you, too.

Best wishes with your ETF relative strength laddering.


JoeyVinyl
124 posts
msg #151715
Ignore JoeyVinyl
4/4/2020 11:55:11 PM

@Cheese

I had a Chartmill subscription for a while. I liked it until they completely redesigned the site. I think they still give good data and analysis but it's harder for me to find things now. I still like to see what they have to say about a stock I'm thinking of buying, though.

As for Relative Strength, I keep in mind a comment I read on these forums from Kevin, I think, on an old post. He was explaining that a high RS doesn't mean the stock is going up if the index is going down. The stock may be going down too, just slower than the index. I won't base my decisions on just the RS. But it is good to know how the stock is doing compared to an index. (Or, as I'll post below, multiple indexes.)

Rate of Return is another thing that I think should never be used by itself. We've all heard the "past performance does not guarantee future results" mantra from financial service companies even while they're patting themselves on the back for how well they've done. It may be a cliche by now, but it's true. I don't know if I'd use it for individual stocks but ETF's seem to be less volatile, even over the last month. Except for some inverse ones and I'm not touching those again.

This may turn out to be a complete bust. Obviously I'm hoping it doesn't. If it doesn't work I can always tell myself it was a learning experience (he said with a chuckle).

JoeyVinyl
124 posts
msg #151716
Ignore JoeyVinyl
4/5/2020 12:02:12 AM

Here's a variation using four different indexes rather than different times from just one. My thinking is that if an ETF is doing better than four of the major indexes (or at least falling slower) then that's better than beating one no matter how many times. I could be way off base here, but I hope I'm not.

Fetcher[
market is ETF

set {ind1, relative strength(^INX,28)} /* S&P 500 Index */
set {ind2, relative strength(^DJIA,28)} /* Dow Jones Industrial Average */
set {ind3, relative strength(^RUI,28)} /* Russell 1000 */
set {ind4, relative strength(^IXIC,28)} /* NASDAQ Composite */
set {rsavg1, ind1 + ind2}
set {rsavg2, ind3 + ind4}
set {rsavg3, rsavg1 + rsavg2}
set {rsavg, rsavg3 / 4}

set {ror07a, close - close 7 days ago}
set {ror07b, ror07a / close}
set {07day, ror07b * 100}

set {ror14a, close - close 14 days ago}
set {ror14b, ror14a / close}
set {14day, ror14b * 100}

set {ror21a, close - close 21 days ago}
set {ror21b, ror21a / close}
set {21day, ror21b * 100}

set {ror28a, close - close 28 days ago}
set {ror28b, ror28a / close}
set {28day, ror28b * 100}

set {avg1, ror07b + ror14b}
set {avg2, ror21b + ror28b}
set {avg3, avg1 + avg2}
set {avg4, avg3 / 4}
set {avgror, avg4 * 100}

rsavg is > 1
avgror is > 0

do not draw rsavg
do not draw avgror
draw ema(14)
draw ema(28)

add column avgror {avg. ror}
add column separator
add column ind1
add column ind2
add column ind3
add column ind4
add column rsavg {rel str}

sort column 5 descending
]




Cheese
1,049 posts
msg #151718
Ignore Cheese
modified
4/5/2020 1:02:23 AM

@JoeyVinyl,

All in good intentions. Thanks again.

You probably referred to an old relative strength discussion between wkloss and Kevin_in_GA.
It was helpful.

I think an old relative strength discussion between glgene and TRO was also helpful.
It came with a practical suggestion: look at wrval when look at relative strength .



Village Elder
230 posts
msg #151725
Ignore Village Elder
4/5/2020 8:45:00 AM

https://www.stockfetcher.com/forums/Filter-Exchange/PORTFOLIO-SELECTION-AND-MANAGEMENT-USING-RISK-REWARD-RATIOS/91296

What you are proposing here seems similar to something Kevin_in_GA posted 10 years ago, but his strategy was to focus on risk-adjusted returns. You have to have noticed that you are selecting doubly or triply leveraged ETFs almost exclusively in your approach. These will take a beating if you are not careful - are you really going to hold a triple leveraged ETF for a month (= 21 trading sessions) in this environment?

I have copied the filter from the above post here. Take a minute to read his first post - if only others would be so thorough and willing to educate others.

Your concept is intriguing but IMHO is ignoring any risk metric in favor of performance - that seems to work until it blows up. GLTY

Fetcher[
SET{21DAYSAGO, CLOSE 21 DAYS AGO}
SET{21DAYRETURN, CLOSE - 21DAYSAGO}
SET{21DAYPERCENTRETURN, 21DAYRETURN / 21DAYSAGO}

SET{RISKFREERETURN, 0.000825}
SET{PERFORMANCE, 21DAYPERCENTRETURN - RISKFREERETURN}

SET{SPY, IND(SPY,CLOSE)}
SET{SPYMA21, CMA(SPY,21)}
SET{SPYSTD, CSTDDEV(SPY,21)}
SET{SPYVOL, SPYSTD / SPYMA21}

SET{ETFSTD, CSTDDEV(CLOSE,21)}
SET{ETFVOL, ETFSTD / MA(21)}

SET{BETA21, ETFVOL / SPYVOL}

/*SHARPE RATIO*/

SET{SHARPE, PERFORMANCE / ETFVOL}

/*TREYNOR RATIO*/

SET{TREYNOR1, PERFORMANCE / BETA21}
SET{TREYNOR, TREYNOR1 * 100}

/*JENSEN'S ALPHA*/

SET{SPY21DAYSAGO, SPY 21 DAYS AGO}
SET{SPY21DAYRETURN, SPY - SPY21DAYSAGO}
SET{SPYRETURN, SPY21DAYRETURN / SPY21DAYSAGO}

SET{SPYPERFORMANCE, SPYRETURN - RISKFREERETURN}
SET{RISKADJUST, BETA21 * SPYPERFORMANCE}
SET{JENSEN1, PERFORMANCE - RISKADJUST}
SET{JENSEN, JENSEN1 * 100}

SYMLIST(SPY,EEM,IWM,SHY,DBA,DBB,DBC,USO,XRT,XME,XHB,KBE,VNQ,VTI,VVR,IWP,IWR,IEF,PCY,BKF,IWC,WIP,VBR)

DRAW SHARPE LINE AT 0
DRAW TREYNOR ON PLOT SHARPE
DRAW JENSEN ON PLOT SHARPE
DRAW MA(21)

ADD COLUMN SHARPE {SHARPE RATIO}
ADD COLUMN TREYNOR {TREYNOR RATIO}
ADD COLUMN JENSEN {JENSEN'S ALPHA}
ADD COLUMN BETA21 {BETA}
SORT ON COLUMN 5 DESCENDING

CHART-TIME IS 63 DAYS
]



Cheese
1,049 posts
msg #151734
Ignore Cheese
4/5/2020 11:51:23 AM

Thank you JoeyVinyl and V E
Your posts and the posts by Kevin_in_GA, wkloss, glgene and TRO referred to above
were helpful to me.

JoeyVinyl
124 posts
msg #151735
Ignore JoeyVinyl
4/5/2020 1:27:28 PM

@Village Elder

That's a good point. I have read that post before, even copied the filter to study later. Now that I have time I'll look into it more. As far as leveraged ETF's go, yes, I can see how this filter would bring those up more often. I'm using it with watchlists of commission free ETF's from my broker rather than the whole ETF market so I'm not seeing those. I changed that to "market is ETF" for posting because obviously you can't see my watchlists.

No, I definitely wouldn't hang on to leveraged ETF's for more than a day, at the most. I did put a few bucks into a couple of them recently. Only on days when the market was going down and watching closely so I could sell for a relatively small profit. One of them went down when I wasn't expecting it to, but I held on and was able to sell it for a small loss the next day when it came close to what I paid. I got lucky. I broke even on those before I realized I'm not ready to mess with them now, if ever.

I do appreciate your feedback. Thank you.

Village Elder
230 posts
msg #151737
Ignore Village Elder
4/5/2020 2:31:41 PM

You are right in not holding these for any appreciable period of time. Your strategy is long only, perhaps with some use of inverse ETFs like SH, but with a month long rotating hold leveraged ETFs are just too volatile.

Your selection metrics are essentially the same - performance and performance relative to another benchmark. Really just the same thing since the highest performers will also be the highest against any given benchmark, so they do not really "corroborate" each other.

Since you are planning to hold for 4 weeks, you might want to consider weekly indicators rather than daily. Also, if you are trading within a 401k there is a three day hold period that may come into play in timing your buys and sells.

JoeyVinyl
124 posts
msg #151741
Ignore JoeyVinyl
modified
4/5/2020 4:27:45 PM

"Your selection metrics are essentially the same - performance and performance relative to another benchmark. Really just the same thing since the highest performers will also be the highest against any given benchmark, so they do not really "corroborate" each other."

True, they don't corroborate each other. I'm using them more for helping me decide. If there are two ETF's with the same Relative Strength I'm going to look at the Rate of Return (and the Sharpe's Ratio* now too), then pick the one that looks best based on the RoR and the chart. Looking at it on a weekly time frame is a good idea too. I'm make a copy for that and see if it changes any of the results.

I've read a lot of old forum posts. Every time I want to learn about an indicator, or think of an idea and want to know what someone here has said about it I go searching the forums. It's quite useful. This idea came about because of some of Kevin's posts about ETF rotation, and to a lesser degree, TRO's Run Forest Run filter. I especially liked Kevin's ideas in his post, A SIMPLE MARKET TIMING FILTER. (https://stockfetcher.com/forums/Filter-Exchange/A-SIMPLE-MARKET-TIMING-FILTER/103064) He was talking about the nine sectors of the S&P 500 and how to trade ETF's that covered those sectors. As he said in that post, "Trading this is simple - buy the ETF with the highest Relative Strength, and sell it and buy the countertrend ETF if it becomes the leader."

This isn't in a 401k, but my broker does have a 3 day hold period for funds after a sale. I took that into account by figuring out just how much I have to invest, then dividing that by 5. The amount per ETF will change every week, of course, depending on if I'm making a profit or not, but this way there will always be something available to buy with while waiting for my last sale to clear.

I always welcome feedback here, and I do appreciate when people point out things I may be missing.

*I'm using only the Sharpe's Ratio because that seemed to be the most useful for this strategy. Like the RoR, it's another good tool to help me decide which ETF would be the best choice.

StockFetcher Forums · Filter Exchange · Making an ETF ladder<< >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2018 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.