StockFetcher Forums · Public Filter List · GUPPY revisited X marks the spot<< >>Post Follow-up
1,089 posts
msg #135381
Ignore graftonian
4/11/2017 4:10:09 PM

Threw this filter together in an attempt to find the spot where the Trader group starts to expand. I used the five day rate of expansion (slope) of the trader group width, both current, and 1 day ago. When the slope goes from negative to positive, they form an "X" on the graph. The more well defined, the better.
Of course, one stills needs support from the Investor group, and a volume spike doesn't hurt.

My plan is to buy at open or pre-market, after an uptrend is confirmed and get out early if it goes south.
BLIN and PGEM look like good candidates tomorrow morning.

Have fun!!!!

/* Guppy MMA */
/* X marks the spot */
market is not OTCBB
Average Volume(30) > 100000
close between .50 and 20

draw EMA(3)
draw EMA(5)
draw EMA(8)
draw EMA(10)
draw EMA(12)
draw EMA(15)

draw EMA(60)
draw EMA(50)
draw EMA(45)
draw EMA(40)
draw EMA(35)
draw EMA(30)
add column separator

/* investor group width */
set{igw, ema(30) - ema(60)}
set{igw2, igw / ema(60)}
set{IGwidth, igw2 * 100}
add column IGwidth

/*trader grp/investor grp separation */
/*The white space between the trader and investor groups*/
set{tradgrpmin, min(ema(3), ema(15))}
set{invgrpmax, max(ema(30), ema(60))}
set{tisep, tradgrpmin - invgrpmax}
set{tisep2, tisep / invgrpmax}
set{TG_IGsep, tisep2 * 100}
add column TG_IGsep
/* "white space" */
TG_IGsep > 0
/* trader group width */
set{tgw, ema(3) - ema(15)}
set{tgw2, tgw / ema(15)}
set{TGwidth, tgw2 * 100}
add column TGwidth
draw TGwidth
draw TGwidth line at 0

add column separator

set{IGX, days(IGwidth < 0, 200)}
add column IGX

set{TGX, days(TGwidth < 0, 100)}
add column TGX
TGX between -1 and 2
/* new section X marks the spot */
set{x1, 5 day slope of TGwidth}
set{x2, 5 day slope of TGwidth 1 day ago}
x1 > 0
x2 < 0
add column x2
add column x1
draw 5 day slope of TGwidth on plot TGwidth
draw 5 day slope TGwidth 1 day ago on plot TGwidth
set{sort, x1 - x2}
add column sort
sort on column 14 descending

/*A couple of bells and whistles for back testing*/
set{entry, close}
set{target, entry * 1.10}
set{ stop, entry * 0.95}
draw price line at entry
draw price line at target
draw price line at stop

chart-time is 100 days
do not draw TGX
do not draw TG_IGsep
do not draw x1
do not draw x2

1,089 posts
msg #135425
Ignore graftonian
4/13/2017 3:35:08 PM

took a long position on ERY late in the day, at 11.50. So far, so good.

1,089 posts
msg #135483
Ignore graftonian
4/17/2017 10:58:23 PM

April 17
Well ERY fizzled. Looking at VSTM,ENZ, and RMTI tomorrow morning.

1 posts
msg #148956
Ignore l50n4rd0
8/20/2019 2:30:37 AM

this is interesting filer , how can someone modified it to find selling opportunity ?

StockFetcher Forums · Public Filter List · GUPPY revisited X marks the spot<< >>Post Follow-up

*** Disclaimer *** does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. does not recommend particular securities., Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.

Copyright 2022 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus

This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.